/* The dataset has the formats below permanently assigned to certain variables. 
   We do NOT need to rerun the DATA step used to assign the formats however
   we DO need to resubmit the PROC FORMAT so SAS will know the translations used */
PROC FORMAT;
VALUE 	GDR 	1 = "Male"
      			2 = "Female";
VALUE 	YN 		1 = "Yes"
				2 = "No";
VALUE EXER 		1 = "High"
				2 = "Moderate"
				3 = "Low";
VALUE TREAT 	1 = "Ran"
				2 = "Sat";
VALUE BMI_TWO 	1 = "< 25"
				2 = "25+";
VALUE BMI_FOUR 	1 = "< 18.5"
				2 = "[18.5, 25)"
				3 = "[25, 30)"
				4 = "30+";
VALUE WT_TWO 	1 = "87kg or Below"
				2 = "More than 87kg";
VALUE WT_FOUR 	1 = "55kg or Below "
				2 = "(55kg, 60kg]"
				3 = "(60kg, 67kg]"
				4 = "(67kg, 79kg]"
				5 = "More than 79kg";
RUN;

/* Wilcoxon-Rank Sum Test (also known as Mann-Whitney U-test) */
/* Non-parametric alternative to Two-Sample T-Test  */
PROC NPAR1WAY DATA=BIO.PULSE_STEP5 WILCOXON; 
CLASS GENDER;   /* Categorical Explanatory Variable */
VAR HEIGHT;     /* Quantitative Response Variable */
RUN;
QUIT;

/* Interestingly, we still use the WILCOXON option to request the
   Kruskal-Wallis test - SAS chooses based upon th number of levels 
   of the categorical explanatory variable */
PROC NPAR1WAY DATA=BIO.PULSE_STEP5 WILCOXON; 
CLASS WTGROUPS;   /* Categorical Explanatory Variable */
/* We can ask for multiple response variables simultaneously */
VAR HEIGHT AGE;  /* Quantitative Response Variable List */
RUN;
QUIT;